#include <ESP8266WiFi.h>

#define pinS0 5 //pin D1, les pin sont mises avec leur n° GPIO, c'est les 3 pins qui actionne le CD4051 pour qu'il sache quelle entrée lire
#define pinS1 4 //pin D2
#define pinS2 0 //pin D3

const char* ssid     = "nom_de_votre_reseau_wifi";
const char* password = "mot_de_passe_de_votre_reseau_wifi";

const char* host = "www.dweet.io";
const char* thing  = "MonCoco"; //nom de l'appareil dans dweet et freeboard
const char* thing_content1 = "Potentio_1"; //nom des variables des 3 potars telles qu'on les retrouveras dans dweet
const char* thing_content2 = "Potentio_2";
const char* thing_content3 = "Potentio_3";

void setup() {
  Serial.begin(115200);
  delay(10);

  // connection au wifi
  Serial.println();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());

  pinMode(pinS0, OUTPUT);
  pinMode(pinS1, OUTPUT);
  pinMode(pinS2, OUTPUT);
}

int value0, value1, value2;//déclaration des 3 variables contenant les valeurs des potars

void loop() {

  delay(1000);

  digitalWrite(pinS2, LOW);
  digitalWrite(pinS1, LOW);
  digitalWrite(pinS0, LOW);
  value0 = analogRead(A0);

  digitalWrite(pinS2, LOW);
  digitalWrite(pinS1, LOW);
  digitalWrite(pinS0, HIGH);
  value1 = analogRead(A0);

  digitalWrite(pinS2, LOW);
  digitalWrite(pinS1, HIGH);
  digitalWrite(pinS0, LOW);
  value2 = analogRead(A0);

  Serial.print("connecting to ");
  Serial.println(host);

  // Utilise WiFiClient class pour créer une connection TCP
  WiFiClient client;
  const int httpPort = 80;
  if (!client.connect(host, httpPort)) {
    Serial.println("connection failed");
    return;
  }

  // Création de la ligne qui va dans la barre d'adresse de dweet, avec les 3 valeurs des potars
  String url = "/dweet/for/";
  url += thing;
  url += "?";
  url += thing_content1;
  url += "=";
  url += value0;
  url += "&";
  url += thing_content2;
  url += "=";
  url += value1;
  url += "&";
  url += thing_content3;
  url += "=";
  url += value2;

  Serial.print("Requesting URL: ");
  Serial.println(url);

  // This will send the request to the server
  client.print(String("GET ") + url + " HTTP/1.1\r\n" +
               "Host: " + host + "\r\n" +
               "Connection: close\r\n\r\n");
  int timeout = millis() + 5000;
  while (client.available() == 0) {
    if (timeout - millis() < 0) {
      Serial.println(">>> Client Timeout !");
      client.stop();
      return;
    }
  }

  // lit toutes les lignes de réponse du serveur et les mets dans le terminal série
  while (client.available()) {
    String line = client.readStringUntil('\r');
    Serial.print(line);
  }

  Serial.println();
  Serial.println("closing connection");
}